Hi @james211
I was hoping to provide an elegant, general purpose solution, but tonight I just banged out some specific code for your application.
I defined the command String as hh:mm:ss*duration where hh is hours, mm is minutes, ss is seconds, and duration is in seconds. So as an example would, to run relay 1 at 6:42:00pm for 10 seconds you would do this using curl:
curl https://api.spark.io/v1/devices/<<device id here>>/setRelay1?access_token=<<access token here>> -d "args=18:42:00*10"
To read back the value do
curl https://api.spark.io/v1/devices/<<device id here>>/getRelay1?access_token=<<access token here>>
You have to follow this format exactly–the parser is very quick and dirty!
Let me know if you have problems.
Here is the code:
// This #include statement was automatically added by the Spark IDE.
#include "SparkTime/SparkTime.h"
UDP UDPClient;
SparkTime rtc;
int relayPin[4] = {D0,D1,D2,D3};
//By relays number
bool isSet[4] = {false,false,false,false};
uint8_t startHours[4] = {0,0,0,0};
uint8_t startMinutes[4] = {0,0,0,0};
uint8_t startSeconds[4] = {0,0,0,0};
unsigned int duration[4] = {0,0,0,0};
unsigned long stopTime[4] = {0,0,0,0};
#define NCHARS 32
char relayStr[4][NCHARS];
void setup()
{
for(int relay=0;relay<4;relay++) {
pinMode(relayPin[relay], OUTPUT);
digitalWrite(relayPin[relay], LOW);
}
Spark.function("setRelay1", setRelay1);
Spark.function("setRelay2", setRelay2);
Spark.function("setRelay3", setRelay3);
Spark.function("setRelay4", setRelay4);
Spark.variable("getRelay1", relayStr[0], STRING);
Spark.variable("getRelay2", relayStr[1], STRING);
Spark.variable("getRelay3", relayStr[2], STRING);
Spark.variable("getRelay4", relayStr[3], STRING);
rtc.begin(&UDPClient, "pool.ntp.org");
rtc.setTimeZone(-5); // gmt offset
rtc.setUseDST(true);
}
void loop() {
unsigned long currentTime = rtc.now();
for(int relay=0;relay<4;relay++) {
if (TRUE==isSet[relay]) {
if (rtc.hour(currentTime)==startHours[relay] &&
rtc.minute(currentTime)==startMinutes[relay] &&
rtc.second(currentTime)==startSeconds[relay]) {
digitalWrite(relayPin[relay],HIGH);
stopTime[relay] = currentTime + duration[relay];
} // start time
} // is set
if (currentTime >= stopTime[relay]) {
digitalWrite(relayPin[relay],LOW);
}
}
delay(100);
}
// Parse the format: 08:56:05*6000 or 18:59:00*10
// hh:mm:ss*duration
int parseTimeDuration(String command, int relay) {
char copyStr[33];
command.toCharArray(copyStr,33);
char *p = strtok(copyStr, ":");
startHours[relay] = (uint8_t)atoi(p);
p = strtok(NULL,":");
startMinutes[relay] = (uint8_t)atoi(p);
p = strtok(NULL,":");
startSeconds[relay] = (uint8_t)atoi(p);
p += 3;
duration[relay] = atoi(p);
isSet[relay] = true;
sprintf(relayStr[relay], "%02d:%02d:%02d*%d",startHours[relay],startMinutes[relay],startSeconds[relay],duration[relay]);
return 1;
}
int setRelay1(String command) {
return parseTimeDuration(command, 0);
}
int setRelay2(String command) {
return parseTimeDuration(command, 1);
}
int setRelay3(String command) {
return parseTimeDuration(command, 2);
}
int setRelay4(String command) {
return parseTimeDuration(command, 3);
}
