I2C Humidity Sensor

Does anyone know how I can communicate with this [1] humidity sensor? It uses I2C but I can’t find any address in the datasheet.

[1] http://datasheet.octopart.com/HIH8120-021-001-Honeywell-datasheet-23707982.pdf

Thanks,
Robert

Hello Robert,
That datasheet seems very brief and limited. While I haven’t used the sensor myself, I think the following document may give you better information. (Note this is for the HIH 6000 series)

Hope this helps!

Mohit

3 Likes

A while back, somebody pointed me to this, which I’ve used to debug I2C issues on a Spark:

// --------------------------------------
// i2c_scanner
//
// http://playground.arduino.cc/Main/I2cScanner
//
// Version 1
//    This program (or code that looks like it)
//    can be found in many places.
//    For example on the Arduino.cc forum.
//    The original author is not know.
// Version 2, Juni 2012, Using Arduino 1.0.1
//     Adapted to be as simple as possible by Arduino.cc user Krodal
// Version 3, Feb 26  2013
//    V3 by louarnold
// Version 4, March 3, 2013, Using Arduino 1.0.3
//    by Arduino.cc user Krodal.
//    Changes by louarnold removed.
//    Scanning addresses changed from 0...127 to 1...119,
//    according to the i2c scanner by Nick Gammon
//    http://www.gammon.com.au/forum/?id=10896
// Version 5, March 28, 2013
//    As version 4, but address scans now to 127.
//    A sensor seems to use address 120.
// 
//
// This sketch tests the standard 7-bit addresses
// Devices with higher bit address might not be seen properly.
//

#include <application.h>

//#include <Wire.h>


void setup()
{
  Wire.begin();

  Serial.begin(9600);
  delay(10000);
  Serial.println("\nI2C Scanner");
}


void loop()
{
  byte error, address;
  int nDevices;

  Serial.println("Scanning...");

  nDevices = 0;
  for(address = 1; address < 127; address++ ) 
  {
    // The i2c_scanner uses the return value of
    // the Write.endTransmisstion to see if
    // a device did acknowledge to the address.
    Wire.beginTransmission(address);
    error = Wire.endTransmission();

    if (error == 0)
    {
      Serial.print("I2C device found at address 0x");
      if (address<16) 
        Serial.print("0");
      Serial.print(address,HEX);
      Serial.println("  !");

      nDevices++;
    }
    else if (error==4) 
    {
      Serial.print("Unknow error at address 0x");
      if (address<16) 
        Serial.print("0");
      Serial.println(address,HEX);
    }    
  }
  if (nDevices == 0)
    Serial.println("No I2C devices found\n");
  else
    Serial.println("done\n");

  delay(5000);           // wait 5 seconds for next scan
}
2 Likes

Thank you guys. It worked.

1 Like

@dougal, that needs to be added to the code snippets @kennethlimcp set up for sure!

2 Likes

@peekay123, thanks for the ping!

@dougal, thanks for the post! i have updated the Spark-Snippets :wink:

github.com/kennethlimcp/Spark-Snippets/blob/master/Snippets/0006%20-%20I2C_scanner.ino

@peekay123, Yeah, I thought about that, but just didn’t have time do to it when I was posting.

@kennethlimcp, Thanks for adding it anyways :smile:

It’s not my original code, as noted in the comments. So all I can claim credit for is bringing it to your attention.

3 Likes