Assistance with UDP Broadcast [Solved]

BulldogLowell · July 7, 2015, 1:27am

Continuing the discussion from Broadcast data to Multiple Cores:

https://github.com/spark/docs/blob/master/docs/firmware.md is a good place to start, I suppose, but the docs are not great. In fairness I haven't tried to write a broadcast packet from the Spark yet! [I have now, it works fine.] My app has a *ix boxes broadcasting and the Spark reading. Code for reading UDP on Spark is complicated up by a bug which means the UDP guarantee of one or zero complete datagrams per read is not guaranteed. You need to read the buffer as if it were a TCP stream looking for a packet delimiter which your sending app must append to the packets. Sending is trivially simple:
  // IPAddress remote_IP_addr( 192, 168, 7, 65); //one remote machine
  
  IPAddress remote_IP_addr( 255, 255, 255, 255); //to broadcast to the entire LAN
  unsigned int remote_port = 2222;

  UDP udp;

  udp.beginPacket( remote_IP, remote_port);
  udp.write( buf);
  udp.endPacket();
Reading should be as simple as this:
  UDP udp;
  udp.start(2222); // in setup() perhaps

  do {
    packetSize = udp.parsePacket();
  } while( 0 == packetSize);

  packetSize = min( sizeof(buf)-1, packetSize);
  udp.read( sbuf, packetSize); // any unread portion of datagram is hereby discarded
  sbuf[packetSize] = '\0'; // assuming this is ascii and you want it terminated

  udp.stop(); //when finished reading packets
but because of the bug I refer to you need to do something like this
  UDP udp;
  udp.start(2222); // not for every packet but until another bug is fixed you need to start and stop at least once a minute

  char c;
  char delim = '\n';
  char *p;

  do {
    packetSize = udp.parsePacket();
  } while( 0 == packetSize);
  packetSize = min( sizeof(buf)-1, packetSize);
  
  p = buf;
  for( i = 0; i < packetSize; i++) {
    udp.read( &c, 1); // remainder of packet is not discarded 
    if( c == delim) {
      *p = '\0'; // if its ascii and you want it terminated
      break;
    }
    *p++ = c;
  }

  udp.stop(); // at least every 60secs

So, I am dredging up this old topic, because I have searched and searched and cannot find what i am doing wrong.

Basically, I have built a set of under-counter LED controllers for the kitchen. They work well, I am using my home automation controller to issue Spark.function() commands (Lua).

So, I now want to use the installed LED device to issue commands to a child device, so... enter Spark.publish() and his friendly cousin Spark.subscribe() . They work brilliantly (bad pun) with a single exception... the approx. one to two seconds it takes for Spark.publish() to make it's way back to the child device, creating a little lag time (which I know is no big deal) but I'd like to minimize that.

Enter UDP... so I have been trying to take advantage of the lightning fast UDP protocol to transmit the new dim value from the Parent to the Child device. When it works, well it works like magic, almost no perceivable delay. But, It isn't stable. So I am posting my code for possible assistance from the forum members who know about this, which clearly I don't.

Here is the Parent Device code:


#include "Bounce2.h"
#include <application.h>

#define EEPROM_STATE_LOCATION 0
#define FADE_DELAY 20
#define POWER_PIN 2
#define FADE_UP_PIN 3
#define FADE_DOWN_PIN 4

#define DEBUG_ON  // Comment out to supress serial output

#define USING_UDP

#ifdef DEBUG_ON
#define DEBUG_PRINT(x) Serial.print(x)
#define DEBUG_PRINTLN(x) Serial.println(x)
#define SERIAL_START(x) Serial.begin(x)
#else
#define DEBUG_PRINT(x)
#define DEBUG_PRINTLN(x)
#define SERIAL_START(x)
#endif

const int ledPin = A6;
const int buttonPin[] = {POWER_PIN, FADE_UP_PIN, FADE_DOWN_PIN};
int oldValue[3];

int currentLevel = 0;

Bounce debouncer[3] = Bounce();

#ifdef USING_UDP
  IPAddress slaveIP(192, 168, 1, 255);
  unsigned int localPort = 2222;
  UDP Udp;
#endif

extern char* itoa(int a, char* buffer, unsigned char radix);

//
void setup()
{
  SERIAL_START(115200);
  pinMode(ledPin, OUTPUT);
  Spark.function("setDimLevel" , incomingDimCommand);
  Spark.variable("currentLevel", &currentLevel, INT);
#ifdef USING_UDP
  Udp.begin(localPort);
#endif
  DEBUG_PRINTLN("Retreiving saved dim level...");
  int storedLevel = EEPROM.read(EEPROM_STATE_LOCATION);
  fadeToLevel(storedLevel);
  currentLevel = storedLevel;
  Spark.publish("newDimValue", String(currentLevel));
  for (int i = 0; i < 3; i++)
  {
    debouncer[i].attach(buttonPin[i]);
    debouncer[i].interval(5);
  }
}
//
void loop()
{
#ifdef USING_UDP
  for (int i = 0; i < 3; i++)
  {
    debouncer[i].update();
    int value = debouncer[i].read();
    if (value != oldValue[i])
    {
      int fadeTarget = 0;
      switch (value)
      {
        case 0:
          fadeTarget = currentLevel? 0 : 100;
          break;
        case 1:
          fadeTarget = min(currentLevel + 10, 100);
          break;
        case 2:
          fadeTarget = max(currentLevel - 10, 0);
          break;
      }
      sendFadeTargetAsUDP(value);
      //Spark.publish("newDimValue", String(fadeTarget));// debugging
      fadeToLevel(fadeTarget);
      oldValue[i] = value;
    }
  }
#endif
}
//
void fadeToLevel(int targetLevel)
{
  int delta = (targetLevel - currentLevel) < 0 ? -1 : 1;
  while ( currentLevel != targetLevel )
  {
    currentLevel += delta;
    analogWrite( ledPin, (int)(currentLevel / 100.0 * 255) );
    delay(FADE_DELAY);
  }
}
//
int incomingDimCommand(String params)
{
  int value = params.toInt();
  value = constrain(value, 0, 100);
#ifdef USING_UDP
  sendFadeTargetAsUDP(value);
#else
  Spark.publish("newDimValue", String(value));
#endif
  fadeToLevel(value);
  DEBUG_PRINT("Set incoming dim level to");
  DEBUG_PRINTLN(value);
  EEPROM.write(EEPROM_STATE_LOCATION, currentLevel);
  return value;
}
//
#ifdef USING_UDP
void sendFadeTargetAsUDP(int slaveTarget)
{
  DEBUG_PRINTLN("sending message via UDP");
  char string1[4] = "";
  itoa(slaveTarget, string1, 10); // 10 radix;
  Udp.beginPacket(slaveIP, localPort);
  Udp.write(string1);
  Udp.write('/0');
  Udp.endPacket();
}
#endif

and the child:


#define EEPROM_STATE_LOCATION 0
#define FADE_DELAY 20
#define UDP_TX_PACKET_MAX_SIZE 25

//#define DEBUG_ON  // Comment out to supress serial output

#define USING_UDP

#ifdef DEBUG_ON

#define DEBUG_PRINT(x) Serial.print(x)#define
#define DEBUG_PRINT2(x,y) Serial.print(x,y)
#define DEBUG_PRINTLN(x) Serial.println(x)
#define SERIAL_START(x) Serial.begin(x)
#else
#define DEBUG_PRINT(x)
#define DEBUG_PRINT2(x,y)
#define DEBUG_PRINTLN(x)
#define SERIAL_START(x)
#endif

const int ledPin = D0;

int currentLevel = 0;

#ifdef USING_UDP
  unsigned int localPort = 2222;
  UDP udp;
#endif

//
void setup()
{
  SERIAL_START(115200);
  DEBUG_PRINTLN("Retreiving saved dim level...");
  int storedLevel = EEPROM.read(EEPROM_STATE_LOCATION);
  fadeToLevel(storedLevel);
  currentLevel = storedLevel;
  pinMode(D0, OUTPUT);
#ifdef USING_UDP
  udp.begin(localPort);
#else
  Spark.function("setDimLevel" , incomingDimCommand);
  Spark.variable("currentLevel", &currentLevel, INT);
  Spark.subscribe("newDimValue", masterRequest, "<REDACTED>");
  Spark.publish("dim_slave", String(currentLevel));
#endif
}
//
void loop()
{
#ifdef USING_UDP
  int packetSize = udp.parsePacket();
  if (packetSize)
  {
    // read the packet into packetBufffer
    char packetBuffer[UDP_TX_PACKET_MAX_SIZE] = "";
    udp.read(packetBuffer, UDP_TX_PACKET_MAX_SIZE);
    DEBUG_PRINTLN("Contents:");
    DEBUG_PRINTLN(packetBuffer);
    int udpValue = atoi(packetBuffer);
    fadeToLevel(udpValue);
  }
#endif
}
//
void fadeToLevel(int targetLevel)
{
  int delta = ( targetLevel - currentLevel ) < 0 ? -1 : 1;
  while ( currentLevel != targetLevel )
  {
    currentLevel += delta;
    analogWrite(ledPin, (int)(currentLevel / 100.0 * 255) );
    delay(FADE_DELAY);
    Spark.process();
  }
  EEPROM.write(EEPROM_STATE_LOCATION, currentLevel);
}
//
int incomingDimCommand(String params)
{
  int value = params.toInt();
  value = constrain(value, 0, 100);
  fadeToLevel(value);
  DEBUG_PRINT("Set incoming dim level to");
  DEBUG_PRINTLN(value);
  return value;
}

#ifdef USING_UDP

#else
void masterRequest(const char *event, const char *data)
{

  String params = String(data);
  int value = params.toInt();
  value = constrain(value, 0, 100);
  fadeToLevel(value);
  Spark.publish("dim_slave_Subscribe", String(currentLevel));// test
  DEBUG_PRINT("Set incoming dim level to");
  DEBUG_PRINTLN(value);
}
#endif

AndyW · July 7, 2015, 1:36am

When you say “unstable” can you be more specific ?

Does one or both of the parent or child crash & restart ?

Does it work, but just not reliably, without either parent or child appearing to reset or hang ?

BulldogLowell · July 7, 2015, 1:38am

Hey Andy,

thanks and good questions… the Parent crashes and restarts. sometimes it seems to work after a restart, other times, no.

Is the (parent) Core’s UDP buffer overloading?

Jim

bko · July 7, 2015, 1:43am

Hi @BulldogLowell

On the Core, the sender receives their own broadcast packets back so you need to be ready for that and read all the broadcast data so that buffers don’t overflow.

So you should add code like if (UDP.parsePacket()) {UDP.read(junkArray, packetSize);} in loop.

BulldogLowell · July 7, 2015, 1:46am

Ja, that makes sense! I'll try that, thanks.

AndyW · July 7, 2015, 1:51am

Ah - you might be falling foul of the old “you hear your own broadcasts” problem.

Try specifying a different port to listen to when you call udp.begin() - by default it listens on the same port it transmits on.

That way the parent won’t hear it’s own messages.

I know that this should not be a problem, but buffers are scarce in the CC3000 and if it ties some up with the received broadcasts, that can cause problems.

So the idea is to call udp.begin() on the parent with a port number that is different than the one you use in udp.beginPacket() and that the children will be listening on.

Just an idea, let us know if it helps at all. UDP is kind of borked on the core, because the CC3000 doesn’t preserve packet boundaries, as long as you code for that, you can survive, but you should be coding with that fact in mind. I believe that the photon does things correctly, however.

BulldogLowell · July 7, 2015, 3:12am

Thanks @AndyW & @bko

I took @bko’s method and added a bit of code to process away the UDP message to the the Parent, and it works nearly flawlessly, almost imperceivable delay in the fading between the two devices. So, I’m going to have to do more of this!!!

Working Parent Code in case anyone comes across this issue:


#include "Bounce2.h"
#include <application.h>

#define EEPROM_STATE_LOCATION 0
#define FADE_DELAY 20
#define POWER_PIN 2
#define FADE_UP_PIN 3
#define FADE_DOWN_PIN 4

#define DEBUG_ON  // Comment out to supress serial output

#define USING_UDP  //  Comment out to switch to Spark.publish() & Spark.subscribe()

#ifdef DEBUG_ON
#define DEBUG_PRINT(x) Serial.print(x)
#define DEBUG_PRINTLN(x) Serial.println(x)
#define SERIAL_START(x) Serial.begin(x)
#else
#define DEBUG_PRINT(x)
#define DEBUG_PRINTLN(x)
#define SERIAL_START(x)
#endif

const int ledPin = A6;
const int buttonPin[] = {POWER_PIN, FADE_UP_PIN, FADE_DOWN_PIN};
int oldValue[3];

int currentLevel = 0;

Bounce debouncer[3] = Bounce();

#ifdef USING_UDP
  #define UDP_TX_PACKET_MAX_SIZE 25
  IPAddress slaveIP(192, 168, 1, 255);
  unsigned int localPort = 2222;
  UDP Udp;
#endif

extern char* itoa(int a, char* buffer, unsigned char radix);

//
void setup()
{
  SERIAL_START(115200);
  pinMode(ledPin, OUTPUT);
  Spark.function("setDimLevel" , incomingDimCommand);
  Spark.variable("currentLevel", &currentLevel, INT);
#ifdef USING_UDP
  Udp.begin(localPort);
#endif
  DEBUG_PRINTLN("Retreiving saved dim level...");
  int storedLevel = EEPROM.read(EEPROM_STATE_LOCATION);
  fadeToLevel(storedLevel);
  currentLevel = storedLevel;
  Spark.publish("newDimValue", String(currentLevel));
  for (int i = 0; i < 3; i++)
  {
    debouncer[i].attach(buttonPin[i]);
    debouncer[i].interval(5);
  }
}
//
void loop()
{
#ifdef USING_UDP
  if (Udp.parsePacket())
  {
    // read the packet into packetBufffer
    char packetBuffer[UDP_TX_PACKET_MAX_SIZE] = "";
    Udp.read(packetBuffer, UDP_TX_PACKET_MAX_SIZE);
    DEBUG_PRINT("UDP bounceback Contents:");
    DEBUG_PRINTLN(packetBuffer);
  }
#endif
  for (int i = 0; i < 3; i++)
  {
    debouncer[i].update();
    int value = debouncer[i].read();
    if (value != oldValue[i])
    {
      int fadeTarget = 0;
      switch (value)
      {
        case 0:
          fadeTarget = currentLevel? 0 : 100;
          break;
        case 1:
          fadeTarget = min(currentLevel + 10, 100);
          break;
        case 2:
          fadeTarget = max(currentLevel - 10, 0);
          break;
      }
#ifdef USING_UDP
      sendFadeTargetAsUDP(value);
#else
      Spark.publish("newDimValue", String(fadeTarget));// debugging
#endif
      fadeToLevel(fadeTarget);
      oldValue[i] = value;
    }
  }
}
//
void fadeToLevel(int targetLevel)
{
  int delta = (targetLevel - currentLevel) < 0 ? -1 : 1;
  while ( currentLevel != targetLevel )
  {
    currentLevel += delta;
    analogWrite( ledPin, (int)(currentLevel / 100.0 * 255) );
    delay(FADE_DELAY);
  }
}
//
int incomingDimCommand(String params)
{
  int value = params.toInt();
  value = constrain(value, 0, 100);
#ifdef USING_UDP
  sendFadeTargetAsUDP(value);
#else
  Spark.publish("newDimValue", String(value));
#endif
  fadeToLevel(value);
  DEBUG_PRINT("I just set incoming dim level to ");
  DEBUG_PRINTLN(value);
  EEPROM.write(EEPROM_STATE_LOCATION, currentLevel);
  return value;
}
//
#ifdef USING_UDP
void sendFadeTargetAsUDP(int slaveTarget)
{
  DEBUG_PRINT("sending message via UDP, message = ");
  char string1[4] = "";
  itoa(slaveTarget, string1, 10); // 10 radix;
  DEBUG_PRINTLN(string1);
  Udp.beginPacket(slaveIP, 2222);
  Udp.write(string1);
  Udp.endPacket();
}
#endif

and the Child:

#define EEPROM_STATE_LOCATION 0
#define FADE_DELAY 20
#define UDP_TX_PACKET_MAX_SIZE 25

#define DEBUG_ON   // Comment out to supress serial output

#define USING_UDP  // Comment out to switch to Spark.publish() & Spark.subscribe()

#ifdef DEBUG_ON
#define DEBUG_PRINT(x) Serial.print(x)
#define DEBUG_PRINT2(x,y) Serial.print(x,y)
#define DEBUG_PRINTLN(x) Serial.println(x)
#define SERIAL_START(x) Serial.begin(x)
#else
#define DEBUG_PRINT(x)
#define DEBUG_PRINT2(x,y)
#define DEBUG_PRINTLN(x)
#define SERIAL_START(x)
#endif

const int ledPin = D0;

int currentLevel = 0;

#ifdef USING_UDP
  unsigned int localPort = 2222;
  UDP udp;
#endif

//
void setup()
{
  SERIAL_START(115200);
  DEBUG_PRINTLN("Retreiving saved dim level...");
  int storedLevel = EEPROM.read(EEPROM_STATE_LOCATION);
  fadeToLevel(storedLevel);
  currentLevel = storedLevel;
  pinMode(D0, OUTPUT);
#ifdef USING_UDP
  udp.begin(localPort);
#else
  Spark.function("setDimLevel" , incomingDimCommand);
  Spark.variable("currentLevel", &currentLevel, INT);
  Spark.subscribe("newDimValue", masterRequest, "<REDACTED>");
  Spark.publish("dim_slave", String(currentLevel));
#endif
}
//
void loop()
{
#ifdef USING_UDP
  if (udp.parsePacket())
  {
    char packetBuffer[UDP_TX_PACKET_MAX_SIZE] = "";
    udp.read(packetBuffer, UDP_TX_PACKET_MAX_SIZE);
    DEBUG_PRINTLN("Contents:");
    DEBUG_PRINTLN(packetBuffer);
    int udpValue = atoi(packetBuffer);
    fadeToLevel(udpValue);
  }
#endif
}
//
void fadeToLevel(int targetLevel)
{
  int delta = ( targetLevel - currentLevel ) < 0 ? -1 : 1;
  while ( currentLevel != targetLevel )
  {
    currentLevel += delta;
    analogWrite(ledPin, (int)(currentLevel / 100.0 * 255) );
    delay(FADE_DELAY);
  }
  EEPROM.write(EEPROM_STATE_LOCATION, currentLevel);
}
//
int incomingDimCommand(String params)
{
  int value = params.toInt();
  value = constrain(value, 0, 100);
  fadeToLevel(value);
  DEBUG_PRINT("Set incoming dim level to");
  DEBUG_PRINTLN(value);
  return value;
}

#ifdef USING_UDP

#else
void masterRequest(const char *event, const char *data)
{

  String params = String(data);
  int value = params.toInt();
  value = constrain(value, 0, 100);
  fadeToLevel(value);
  Spark.publish("dim_slave_Subscribe", String(currentLevel));// test
  DEBUG_PRINT("Set incoming dim level to");
  DEBUG_PRINTLN(value);
}
#endif

THANKS!!!

Topic		Replies	Views
Basic draft of a network communication between java and the spark Tutorials	5	2376	May 28, 2014
I'm having a problem getting UDP traffic from my spark cores Troubleshooting	13	3271	July 13, 2014
[Solved/Workaround] Spark Core can't send UDP broadcast packets without cloud connection Troubleshooting	26	10433	December 23, 2014
Simple UDP program breaks the core Troubleshooting	89	14757	October 9, 2014
Receive UDP Broadcast packet [SOLVED] Troubleshooting	4	3225	February 14, 2014

Assistance with UDP Broadcast [Solved]

Related Topics