# I2C Humidity Sensor

**URL:** <https://community.particle.io/t/i2c-humidity-sensor/5451>\
**Category:** General\
**Created:** [June 30, 2014, 4:37pm UTC](https://community.particle.io/t/i2c-humidity-sensor/5451 "2014-06-30T16:37:10Z")\
**Posts on this page:** 7\
**Page:** 1

<div class="post-metadata">

**Author:** ![robertdolca](https://sea2.discourse-cdn.com/flex026/user_avatar/community.particle.io/robertdolca/32/20796_2.png) [@robertdolca](https://community.particle.io/u/robertdolca)\
**Post date:** [June 30, 2014, 4:37pm UTC](https://community.particle.io/t/i2c-humidity-sensor/5451/1 "2014-06-30T16:37:10Z")

</div>

Does anyone know how I can communicate with this [1] humidity sensor? It uses I2C but I can’t find any address in the datasheet.

[1] [http://datasheet.octopart.com/HIH8120-021-001-Honeywell-datasheet-23707982.pdf](http://datasheet.octopart.com/HIH8120-021-001-Honeywell-datasheet-23707982.pdf)

Thanks,  
Robert

---

<div class="post-metadata">

**Author:** ![mohit](https://sea2.discourse-cdn.com/flex026/user_avatar/community.particle.io/mohit/32/1971_2.png) [@mohit](https://community.particle.io/u/mohit)\
**Post date:** [June 30, 2014, 5:50pm UTC](https://community.particle.io/t/i2c-humidity-sensor/5451/2 "2014-06-30T17:50:23Z")

</div>

Hello Robert,  
That datasheet seems very brief and limited. While I haven’t used the sensor myself, I think the following document may give you better information. (Note this is for the HIH 6000 series)

> **[I2CCommunications.pdf](https://phanderson.com/arduino/I2CCommunications.pdf)**
>
> 133.13 KB

Hope this helps!

Mohit

---

<div class="post-metadata">

**Author:** ![dougal](https://sea2.discourse-cdn.com/flex026/user_avatar/community.particle.io/dougal/32/20713_2.png) [@dougal](https://community.particle.io/u/dougal)\
**Post date:** [June 30, 2014, 8:10pm UTC](https://community.particle.io/t/i2c-humidity-sensor/5451/3 "2014-06-30T20:10:22Z")

</div>

A while back, somebody pointed me to this, which I’ve used to debug I2C issues on a Spark:

```
// --------------------------------------
// i2c_scanner
//
// http://playground.arduino.cc/Main/I2cScanner
//
// Version 1
// This program (or code that looks like it)
// can be found in many places.
// For example on the Arduino.cc forum.
// The original author is not know.
// Version 2, Juni 2012, Using Arduino 1.0.1
// Adapted to be as simple as possible by Arduino.cc user Krodal
// Version 3, Feb 26 2013
// V3 by louarnold
// Version 4, March 3, 2013, Using Arduino 1.0.3
// by Arduino.cc user Krodal.
// Changes by louarnold removed.
// Scanning addresses changed from 0...127 to 1...119,
// according to the i2c scanner by Nick Gammon
// http://www.gammon.com.au/forum/?id=10896
// Version 5, March 28, 2013
// As version 4, but address scans now to 127.
// A sensor seems to use address 120.
// 
//
// This sketch tests the standard 7-bit addresses
// Devices with higher bit address might not be seen properly.
//

#include <application.h>

//#include <Wire.h>

void setup()
{
  Wire.begin();

  Serial.begin(9600);
  delay(10000);
  Serial.println("\nI2C Scanner");
}

void loop()
{
  byte error, address;
  int nDevices;

  Serial.println("Scanning...");

  nDevices = 0;
  for(address = 1; address < 127; address++ ) 
  {
    // The i2c_scanner uses the return value of
    // the Write.endTransmisstion to see if
    // a device did acknowledge to the address.
    Wire.beginTransmission(address);
    error = Wire.endTransmission();

    if (error == 0)
    {
      Serial.print("I2C device found at address 0x");
      if (address<16) 
        Serial.print("0");
      Serial.print(address,HEX);
      Serial.println(" !");

      nDevices++;
    }
    else if (error==4) 
    {
      Serial.print("Unknow error at address 0x");
      if (address<16) 
        Serial.print("0");
      Serial.println(address,HEX);
    }    
  }
  if (nDevices == 0)
    Serial.println("No I2C devices found\n");
  else
    Serial.println("done\n");

  delay(5000); // wait 5 seconds for next scan
}

```

---

<div class="post-metadata">

**Author:** ![robertdolca](https://sea2.discourse-cdn.com/flex026/user_avatar/community.particle.io/robertdolca/32/20796_2.png) [@robertdolca](https://community.particle.io/u/robertdolca)\
**Post date:** [June 30, 2014, 10:50pm UTC](https://community.particle.io/t/i2c-humidity-sensor/5451/4 "2014-06-30T22:50:18Z")

</div>

Thank you guys. It worked.

---

<div class="post-metadata">

**Author:** ![peekay123](https://sea2.discourse-cdn.com/flex026/user_avatar/community.particle.io/peekay123/32/810_2.png) [@peekay123](https://community.particle.io/u/peekay123)\
**Post date:** [July 1, 2014, 2:43am UTC](https://community.particle.io/t/i2c-humidity-sensor/5451/5 "2014-07-01T02:43:52Z")

</div>

@dougal, that needs to be added to the code snippets @kennethlimcp set up for sure!

> **[Spark Code-Snippets](https://community.particle.io/t/spark-code-snippets/5385)**
>
> There’s an increasing number of people asking about the same code issues they are experiencing and the WEB IDE hasn’t been able to support this just yet. So @peekay123 was came up with the idea and probably off to bed at 1.30am so i shall take the...

---

<div class="post-metadata">

**Author:** ![kennethlimcp](https://avatars.discourse-cdn.com/v4/letter/k/c0e974/32.png) [@kennethlimcp](https://community.particle.io/u/kennethlimcp)\
**Post date:** [July 1, 2014, 8:10am UTC](https://community.particle.io/t/i2c-humidity-sensor/5451/6 "2014-07-01T08:10:03Z")

</div>

@peekay123, thanks for the ping!

@dougal, thanks for the post! i have updated the Spark-Snippets 😉

[github.com/kennethlimcp/Spark-Snippets/blob/master/Snippets/0006%20-%20I2C\_scanner.ino](https://github.com/kennethlimcp/Spark-Snippets/blob/master/Snippets/0006%20-%20I2C_scanner.ino)

---

<div class="post-metadata">

**Author:** ![dougal](https://sea2.discourse-cdn.com/flex026/user_avatar/community.particle.io/dougal/32/20713_2.png) [@dougal](https://community.particle.io/u/dougal)\
**Post date:** [July 1, 2014, 2:46pm UTC](https://community.particle.io/t/i2c-humidity-sensor/5451/7 "2014-07-01T14:46:50Z")

</div>

@peekay123, Yeah, I thought about that, but just didn’t have time do to it when I was posting.

@kennethlimcp, Thanks for adding it anyways 😄

It’s not my original code, as noted in the comments. So all I can claim credit for is bringing it to your attention.